update 2001/11/20

BACK: UP: NEXT: ENGLISH:

種々の軌道角運動量と磁気量子数

l=1,m=-1,+1

球面調和関数Y[lm]のl,mは,量子力学の軌道角運動量と磁気量子数です. ここでは,小さいlに対するグラフを幾つか表示してみます.やり方は,前項 と同様,媒介変数を用いてx,y,zを表す方法です.

mが奇数の場合は球面調和関数はexp(-imφ)の項の為に虚部を持ちます. m=-1,1ののこの関数は次のようになります.

   Y[1,-1](t,p) =  sqrt(3/8pi) sin(t) exp(-i p)
   Y[1, 1](t,p) = -sqrt(3/8pi) sin(t) exp( i p)

|Y|^2はYとその複素共役をかければよく,上の2つの式はいづれも同じY (θ)=3/8π sin^2θ となります.なお,球面調和関数の複素共役は簡単に求 めることができ, (Y[l,m])^* = (-1)^m Y[l,-m] で与えられます. つまり,mの符号を変え,さらにmが奇数の場合は全体の符号を変えます.

gnuplot> set parametric

	dummy variable is t for curves, u/v for surfaces
gnuplot> set angle degree
gnuplot> set urange [0:360]
gnuplot> set vrange [0:360]
gnuplot> set isosample 18,18
gnuplot> set ticslevel 0
gnuplot> set size 0.65,1.0
gnuplot> a=3.0/(8*pi)
gnuplot> fx(u,v)=cos(u)*cos(v)
gnuplot> fy(u,v)=sin(u)*cos(v)
gnuplot> fz(v)=sin(v)
gnuplot> g(v)=cos(v)*cos(v)
gnuplot> splot a*g(v)*fx(u,v),a*g(v)*fy(u,v),a*g(v)*fz(v)
sph11

左がY[11]を自乗したグラフで,z軸を主軸にしたトーラスとなります.但し 内側に穴はありません.関数はsin(θ)を含みますが,角度θをvで 表すとcos(v)になるので, g(v)=cos(v)*cos(v)と関数定義して います.



l=2,m=-2,-1,0,+1,+2

l=2のときは,磁気量子数mが -2〜2 までの5つの関数があります.それぞれの 関数は以下で与えられます.

   Y[2,-2](t,p) =  sqrt(15/32pi) sin(t)sin(t) exp(-2i p)
   Y[2,-1](t,p) =  sqrt(15/8pi) sin(t)cos(t) exp(-i p)
   Y[2, 0](t,p) =  sqrt(5/16pi) (3cos(t)cos(t)-1)
   Y[2, 1](t,p) = -sqrt(15/8pi) sin(t)cos(t) exp( i p)
   Y[2, 2](t,p) =  sqrt(15/32pi) sin(t)sin(t) exp( 2i p)

自乗にして表示すると|m|が同じものは同じグラフになりますので,m=0,1,2の 3つの場合について表示します.

m=0

gnuplot> a= 5.0/(16*pi)
gnuplot> g(v)= (3*sin(v)*sin(v)-1)**2
gnuplot> splot a*g(v)*fx(u,v),a*g(v)*fy(u,v),a*g(v)*fz(v)
sph20

m=1

gnuplot> a=15.0/( 8*pi)
gnuplot> g(v)= (sin(v)*cos(v))**2
gnuplot> splot a*g(v)*fx(u,v),a*g(v)*fy(u,v),a*g(v)*fz(v)
sph21

m=2

gnuplot> a=15.0/(32*pi)
gnuplot> g(v)= (cos(v)*cos(v))**2
gnuplot> splot a*g(v)*fx(u,v),a*g(v)*fy(u,v),a*g(v)*fz(v)
sph22



BACK: UP: NEXT: ENGLISH: